set dir=%1
rem --- Anfuehrungszeichen entfernen ---
set dir=%dir:~1,-1%
rem --- Verzeichnisgroesse bestimmen (wird durch 10 geteilt, da nur 31 bit plus Vorzeichen zur Verfügung stehen!) ---
for /r "%dir%" %%F in (*.*) do set /a sz=sz+%%~zF/10
set lw=%2
if not "%lw%"=="" goto lwok
%nero% --listdrives
del neroerr.txt
set /p lw=Bitte Laufwerksbuchstaben angeben:
rem --- hier weiter, wenn Brenner ausgewaehlt ---
:lwok
rem --- Parameter, die immer gesetzt werden ---
set typ=CD
set para=--write --drivename %lw:~0,1% --real --recursive "%dir%\*.*" --underrun_prot --create_iso_fs
rem --- wenn DVD-Video ohne VIDEO_TS, dann anlegen ---
if exist "%dir%\VIDEO_TS.IFO" (md "%dir%\VIDEO_TS"&&move "%dir%\*.*" "%dir%\VIDEO_TS")
rem --- wenn DVD-Video, dann Parameter ergaenzen ---
if exist "%dir%\VIDEO_TS\VIDEO_TS.IFO" (set typ=DVD-VIDEO&&set para=%para% --DVD --iso-no-joliet --dvdvideo_realloc --dvdvideo_cmpt&&goto kuerzen)
rem --- wenn zu gross fuer CD, dann DVD ---
if %sz% geq 73500000 (set typ=DVD&&set para=%para% --DVD)
rem --- Pfad auf letztes Verzeichnis kuerzen als CD/DVD-Namen ---
:kuerzen
echo %dir% | find "\"
if not errorlevel 1 (set dir=%dir:~1%&&goto kuerzen)
rem --- CD/DVD-Namen uebergeben (muss vor dem Verzeichnis angegeben werden!!!) ---
set para=--iso "%dir%" %para%
rem --- BRENNEN ---
%nero% %para%
echo.
echo.
rem --- bei Fehler neroerr.txt oeffnen, sonst loeschen und Fertig-Meldung ---
if errorlevel 1 (neroerr.txt) else (
del neroerr.txt
cls
echo.
echo Die %typ% "%dir%" wurde erfolgreich auf %lw%: gebrannt!
echo.
pause )