Datensatzrettung für beschädigte Tabellen

Teil 1  
Versionen: Access 2013/2010 (32- und 64-Bit), 2007 und Office 365 (Access)  
  
Wenn keine regelmäßige Komprimierung erfolgt oder Datenbanken von mehreren Anwendern gleichzeitig genutzt werden, müssen Sie immer wieder mit Problemen rechnen. Einzelne Objekte können nicht mehr geöffnet oder bearbeitet werden, beim Zugriff auf Daten werden Fehlermeldungen angezeigt oder Access stürzt komplett ab. Trotzdem sind damit nicht unbedingt alle Datensätze verloren und können in großen Teilen gerettet werden. Wir zeigen in diesem Tipp wie Sie dazu vorgehen müssen.  
  
Zunächst ein paar Grundlagen: Access speichert neue oder geänderte Datensätze nicht an festen Positionen innerhalb der ACCDB-/MDB-Datei, sondern fügt sie beim Anlegen oder nach einer Bearbeitung am Ende der Datei an. Die genaue Position wird als "Pointer" in einer Art "Inhaltsverzeichnis" festgehalten. Über dieses Inhaltsverzeichnis mit seinen Pointern erfolgt dann später der Zugriff. Sind einzelne Datensätze nicht mehr lesbar, ist das Inhaltsverzeichnis beschädigt worden und einzelne Pointer verweisen auf ungültige Speicherorte. Andere Pointer verweisen nach wie vor auf den korrekten Speicherort, so dass sich diese Datensätze durchaus retten lassen. Liegt in solchen Fällen keine Datensicherung vor oder haben Sie seit der letzten Sicherung sehr viele Daten neu erfasst oder geändert, können Sie zunächst versuchen, Datensatz für Datensatz per *Bearbeiten-Kopieren* und *Bearbeiten-Am Ende Einfügen* in eine neu angelegte Tabelle gleicher Struktur zu übertragen - ein recht mühsames und fehlerträchtiges Unterfangen.  
  
Das Anlegen der neuen Tabelle mit gleicher Struktur und die Übertragung der noch intakten Datensätze lässt sich jedoch per VBA automatisieren. Dazu legen Sie sich in jeder neuen Datenbank ein Formular "Datensätze retten" an oder übertragen es aus einer damit bereits ausgestatteten Datenbank per *Datei-Externe Daten-Importieren* (bis Access 2003) bzw. über das Register "Externe Daten", Gruppe "Importieren", Symbol *Access* (ab Access 2007) in neue Datenbanken. Das Formular bauen Sie folgendermaßen auf:

* Legen Sie ein neues, leeres Formular an und speichern Sie es unter dem Namen "Datensätze retten".
* Legen Sie im Formular ein Kombinationsfeld mit dem Namen "cboxTables" und der Beschriftung "Beschädigte Tabelle:" an.
* Kopieren Sie folgende SQL-Anweisung in die Eigenschaft "Datensatzherkunft" des Kombinationsfeldes:

SELECT Name FROM MSysObjects WHERE Left$([Name],1)<>"~" AND Left$([Name],4) <> "MSys" AND Left$([Name],4) <> "USys" AND Type=1 ORDER BY Name;

* Kopieren Sie die folgenden Anweisungen in die Ereignisprozedur "Nach Aktualisierung" des Kombinationsfeldes:

  Dim strBadTable As String  
  
  strBadTable = Me.cboxTables  
  Me.cboxFields.RowSource = strBadTable  
  Me.txtNewTable = strBadTable & "/Neu"

* Legen Sie ein weiteres Kombinationsfeld mit dem Namen "cboxFields" und der Beschriftung "Primärschlüssel:" an.
* Stellen Sie die Eigenschaft "Herkunftstyp" des Kombinationsfeldes auf den Eintrag "Feldliste".
* Legen Sie ein neues Textfeld mit dem Namen "txtNewTable" und der Beschriftung "Neue Tabelle:" an.
* Legen Sie eine Schaltfläche mit dem Namen "btnDoIt" und der Beschriftung "Übertragen" an.

Speichern Sie die bisherigen Arbeiten, verlassen Sie die Entwurfsansicht des Formulars und schließen Sie die VBA-Entwicklungsumgebung. Wie es weitergeht, erläutern wir im in der nächsten Ausgabe.

Datensatzrettung für beschädigte Tabellen, Teil 2  
Versionen: Access 2013/2010 (32- und 64-Bit), 2007 und Office 365 (Access)  
  
Wenn keine regelmäßige Komprimierung erfolgt oder Datenbanken von mehreren Anwendern gleichzeitig genutzt werden, müssen Sie in Ihren Access-Datenbanken immer wieder mit Inkonsistenzen rechnen. Einzelne Objekte können nicht mehr geöffnet oder bearbeitet werden, beim Zugriff auf Daten werden Fehlermeldungen angezeigt oder Access stürzt komplett ab. Trotzdem sind damit nicht unbedingt alle Datensätze verloren und können in großen Teilen gerettet werden. Unser Tipp zeigt die notwendigen Rettungsmaßnahmen.  
  
Im ersten Teil hatten wir begonnen, ein Formular "Datensätze retten" aufzubauen, das Sie bei Problemen zur Datensatzrettung verwenden können. Öffnen Sie das Formular zunächst in der Entwurfsansicht und fahren Sie folgendermaßen fort:

* Kopieren Sie die folgenden Anweisungen in die Ereignisprozedur "Beim Klicken" der Schaltfläche:

  Dim strBadTable As String  
  Dim strNewTable As String  
  Dim strIdxField As String  
  Dim db As DAO.Database  
  Dim rsBad As DAO.Recordset  
  Dim rsNew As DAO.Recordset  
  Dim cntRecords As Long  
  Dim cntBad As Long  
  Dim cntGood As Long  
  Dim I As Long  
  
  On Error Resume Next  
  strBadTable = Me.cboxTables  
  strIdxField = Me.cboxFields  
  strNewTable = Me.txtNewTable  
  If Err <> 0 Then  
    Beep  
    MsgBox "Bitte Einstellungen prüfen..."  
    Exit Sub  
  End If  
  On Error GoTo 0  
  
  'Beschädigte Tabelle vorbereiten  
  Set db = CurrentDb()  
  Set rsBad = db.OpenRecordset(strBadTable, dbOpenDynaset)  
  rsBad.MoveLast  
  cntRecords = rsBad.RecordCount  
  rsBad.MoveFirst  
  
  'Neue Tabelle vorbereiten  
  DoCmd.SetWarnings False  
  DoCmd.RunSQL "SELECT [" & strBadTable & "].\* " & \_  
               "INTO " & \_  
               "[" & strNewTable & "] " & \_  
               "FROM [" & strBadTable & "] " & \_  
               "WHERE 1=0;", False  
  DoCmd.RunSQL "DELETE \* FROM [" & strNewTable & "];"  
  Set rsNew = db.OpenRecordset(strNewTable, dbOpenDynaset)  
  
  'Datensätze übertragen  
  On Error Resume Next  
  Do While Not rsBad.EOF  
    rsNew.AddNew  
    Err = 0  
    For I = 0 To rsBad.Fields.Count - 1  
      rsNew(I) = rsBad(I)  
    Next I  
    If Err <> 0 Then  
      Beep  
      MsgBox "Datensatz mit Primärschlüssel '" & \_  
             rsBad(strIdxField) & "' konnte nicht " & \_  
             "übertragen werden!", \_  
             vbOKOnly + vbExclamation, \_  
             "Datensätze retten"  
      cntBad = cntBad + 1  
    Else  
      rsNew.Update  
      cntGood = cntGood + 1  
    End If  
    rsBad.MoveNext  
    DoEvents  
  Loop  
  rsBad.Close  
  rsNew.Close  
  Beep  
  MsgBox "Von " & CStr(cntRecords) & \_  
         " Datensätzen konnten " & CStr(cntGood) & \_  
         " Datensätze übertragen werden. " & \_  
         CStr(cntBad) & " Datensätze sind beschädigt " & \_  
         " und konnten nicht übertragen werden...", \_  
         vbOKOnly + vbInformation, "Datensätze retten"

* Wählen Sie das Menü *Extras-Verweise* an und setzen Sie unter Access 2002 und 2003, sofern nicht bereits vorhanden, eine Referenz auf "Microsoft DAO 3.6 Object Library". Unter Access 2013, 2010 und 2007 prüfen Sie, ob eine Referenz auf "Microsoft Office 12.0|14.0|15.0 Access Database Engine Object Library" eingerichtet ist und ergänzen diese ggf.
* Speichern Sie die Änderungen und lassen Sie das Formular anzeigen.

Die Bedienung des Formulars ist schnell erklärt: Das Kombinationsfeld *Beschädigte Tabelle* listet alle Tabellen der aktuellen Datenbank auf. Wählen Sie hier die Tabelle aus, die Ihnen Probleme bereitet und stellen Sie unter *Primärschlüsselfeld* das Feld ein, das in der Tabelle als Primärschlüssel festgelegt ist. Diese Information erlaubt es unter Umständen, bei einem nicht mehr komplett lesbaren Datensatz zumindest noch den Primärschlüssel für eine spätere Rekonstruktion zu ermitteln. Im Feld *Neue Tabelle* geben Sie den Namen der Tabelle an, in die die noch zu rettenden Datensätze übertragen werden sollen. Ein Klick auf *Übertragen* startet dann die Datenrettung. Am Ende wird eine Meldung angezeigt, die Sie darüber informiert, wie viele Datensätze erfolgreich übertragen wurden.  
  
Zur Funktionsweise der Lösung: Das Kombinationsfeld *Beschädigte Tabelle* listet alle Tabellen der aktuellen Datenbank auf, indem es die notwendigen Informationen über ein SQL-Statement aus der Systemtabelle "MSysObjects" ausliest. Bei der Liste *Primärschlüsselfeld* können wir es uns wieder einfach machen: Deren Eigenschaft "Herkunftstyp" ist auf "Feldliste" eingestellt, so dass die Liste durch Zuweisung des Tabellennamens zur Eigenschaft "Datensatzherkunft" automatisch alle Felder der jeweiligen Tabelle anzeigt. Dreh- und Angelpunkt der Lösung ist schließlich die Ereignisprozedur "Beim Klicken" der Schaltfläche *Übertragen*: Im ersten Schritt werden die Einstellungen aus dem Formular ausgelesen und in Variablen übertragen. Fehlen Eingaben, wird eine entsprechende Meldung angezeigt und die Routine verlassen. Danach wird die beschädigte Tabelle als Recordset geöffnet und die Anzahl der enthaltenen Datensätze festgestellt. Anschließend wird die neue Tabelle für die Aufnahme noch intakter Datensätze initialisiert. Per SQL-Statement legen wir die neue Tabelle mit Struktur, aber ohne Datensätze an. "SELECT INTO" wird normalerweise eingesetzt, um Datensätze aus einer Tabelle in eine andere Tabelle zu kopieren. Ist die Zieltabelle nicht vorhanden, wird sie automatisch mit der Struktur der Quelltabelle angelegt. In einer Schleife gehen wir dann alle Datensätze durch und kopieren die Inhalte der noch lesbaren Datensätze in die neue Tabelle.